flake/flake.nix at main · accentor/flake · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
{
  description = "A modern music server focusing on metadata";
  inputs = {
    api = {
      url = "github:accentor/api/v0.24.0";
      inputs = {
        devshell.follows = "devshell";
        nixpkgs.follows = "nixpkgs";
      };
    };
    web = {
      url = "github:accentor/web/v0.35.0";
      inputs = {
        devshell.follows = "devshell";
        nixpkgs.follows = "nixpkgs";
      };
    };
    devshell = {
      url = "github:numtide/devshell";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixpkgs.url = "https://channels.nixos.org/nixos-unstable/nixexprs.tar.zst";
  };
  outputs = inputs:
    {
      packages = builtins.mapAttrs
        (system: pkgs: {
          accentor-api = inputs.api.packages.${system}.default;
          accentor-web = inputs.web.packages.${system}.default;
        })
        inputs.nixpkgs.legacyPackages;
      devShells = builtins.mapAttrs
        (system: pkgs':
          let
            pkgs = pkgs'.extend inputs.devshell.overlays.default;
          in
          {
            flake = pkgs.devshell.mkShell {
              name = "Accentor flake";
              packages = [ pkgs.nixpkgs-fmt ];
            };
            default = inputs.self.devShells.${system}.flake;
          })
        inputs.nixpkgs.legacyPackages;
      nixosModules = {
        accentor = import ./default.nix;
        default = inputs.self.nixosModules.accentor;
      };
      overlays.default = (self: super: {
        accentor-api = inputs.api.packages.${self.stdenv.hostPlatform.system}.default;
        accentor-web = inputs.web.packages.${self.stdenv.hostPlatform.system}.default;
      });
    };
}