json2dir/default.nix at main · alurm/json2dir · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
{
  check-coverage,
  report ? false,
}:
let
  function =
    args@{
      scdoc,
      installShellFiles,
      lib,
      ...
    }:
    (
      if check-coverage then
        let
          toolchain = args.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
        in
        args.makeRustPlatform {
          rustc = toolchain;
          cargo = toolchain;
        }
      else
        args.rustPlatform
    ).buildRustPackage
      {
        pname = "json2dir";
        version = "0.1.0";
        src = ./.;

        cargoHash = "sha256-EJ4yR/PXRW1dyC3ejjknC7sEJFedV6YRfC7DvFMUBIU=";

        nativeBuildInputs = [
          scdoc
          installShellFiles
        ];

        postInstall = ''
          scdoc < ./json2dir.1.scd > json2dir.1
          installManPage json2dir.1
        '';

        meta = {
          homepage = "https://github.com/alurm/json2dir";
          license = lib.licenses.mit;
          description = "Program to convert JSON expressions to directory trees";
        };

        nativeCheckInputs = (
          if check-coverage then
            with args;
            [
              jq
              cargo-llvm-cov
            ]
          else
            [ ]
        );

        checkPhase = ''
          runHook preCheck

          ${
            if check-coverage then
              (
                if report then
                  "./scripts/test-and-collect-coverage --html --output-dir $out"
                else
                  "./scripts/helpers/test-and-check-for-full-coverage"
              )
            else
              "./scripts/test"
          }

          runHook postCheck
        '';
      };
  args = builtins.functionArgs function;
  toArgs = builtins.foldl' (old: new: old // { ${new} = false; }) { };
in
{
  __functor = _: function;
  __functionArgs =
    args
    // toArgs (
      if check-coverage then
        [
          "rust-bin"
          "jq"
          "cargo-llvm-cov"
          "makeRustPlatform"
        ]
      else
        [ "rustPlatform" ]
    );
}