add hallucinator pkg

Author: pogoba

flake-packages.nix

@@ -45,6 +45,9 @@
       claude-monitor = pkgs.callPackage ./pkgs/claude-monitor.nix {
         inherit (inputs) claude-monitor-src;
       };
+      hallucinator = pkgs.callPackage ./pkgs/hallucinator.nix {
+        inherit (inputs) hallucinator-src;
+      };
       hifiscan = pkgs.hifiscan.overrideAttrs (final: prev: {
         buildInputs = prev.buildInputs ++ [ pkgs.wrapGAppsHook3 pkgs.wrapGAppsHook4 ];
       });

flake.lock

@@ -146,6 +146,9 @@
 
     claude-monitor-src.url = "github:Maciek-roboblog/Claude-Code-Usage-Monitor";
     claude-monitor-src.flake = false;
+
+    hallucinator-src.url = "github:gianlucasb/hallucinator";
+    hallucinator-src.flake = false;
   };
 
   outputs = {

flake.nix

@@ -0,0 +1,38 @@
+{
+  hallucinator-src,
+  lib,
+  rustPlatform,
+  pkg-config,
+  fontconfig,
+}:
+
+rustPlatform.buildRustPackage {
+  pname = "hallucinator";
+  version = "0.2.1";
+
+  src = hallucinator-src;
+  sourceRoot = "source/hallucinator-rs";
+
+  # no vendor hash to maintain: crate hashes come from the lock file
+  cargoLock.lockFile = "${hallucinator-src}/hallucinator-rs/Cargo.lock";
+
+  nativeBuildInputs = [
+    rustPlatform.bindgenHook # mupdf-sys generates bindings from vendored mupdf
+    pkg-config
+  ];
+
+  buildInputs = [
+    fontconfig # yeslogic-fontconfig-sys links the system library
+  ];
+
+  # tests query online academic databases (CrossRef, arXiv, DBLP, ...)
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Detect hallucinated references in academic papers";
+    homepage = "https://github.com/gianlucasb/hallucinator";
+    license = licenses.agpl3Plus;
+    mainProgram = "hallucinator-tui";
+    platforms = platforms.unix;
+  };
+}