firmware/.justfile at main · wildbitscomputing/firmware · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
build_dir := "shipping"
firmware_dir := "shipping/firmware"
samples_dir := "shipping/samples"
fpga_dir := "shipping/fpga"
release_zip := "firmware.zip"
fman_dir := `realpath extern`

basic:
    #!/bin/sh
    cd extern/superbasic/source
    make -B updatekernel updateassets build
    cd ../../..
    cp extern/superbasic/.build/sb0?.bin {{firmware_dir}}/gen1/
    cd extern/superbasic/source
    make -B build HARDWARE_GEN=2
    cd ../../..
    cp extern/superbasic/.build/sb0?.bin {{firmware_dir}}/gen2/

basicgh:
    #!/bin/sh
    python3 getghrelease.py FoenixRetro f256-superbasic zip

dos:
    #!/bin/sh
    cd extern/dos
    make dos_jr.bin
    cd ../..
    cp extern/dos/dos_jr.bin {{firmware_dir}}/dos.bin

kernel:
    #!/bin/sh
    cd extern/microkernel
    make
    cd ../..
    cp extern/microkernel/3?.bin {{firmware_dir}}

pexec:
    #!/bin/sh
    cd extern/pexec
    merlin32 -V pexec.s
    cd ../../
    cp extern/pexec/pexec.bin {{firmware_dir}}

wgetclean:
    #!/bin/sh
    cd extern/F256_wget
    make clean
    make
    cd ../..
    cp extern/F256_wget/wget.bin {{firmware_dir}}

wget:
    #!/bin/sh
    cd extern/F256_wget
    make
    cd ../..
    cp extern/F256_wget/wget.bin {{firmware_dir}}

docs:
    #!/bin/sh
    cd extern/docs
    make
    cd ../..
    cp extern/docs/bin/help.bin {{firmware_dir}}
    cp extern/docs/bin/docs/docs_superbasic?.bin {{firmware_dir}}
    cp extern/docs/bin/docs/docs_superbasic_ref_1.bin {{firmware_dir}}/docs_superbasic3.bin
    cp extern/docs/bin/docs/docs_superbasic_ref_2.bin {{firmware_dir}}/docs_superbasic4.bin

xdev:
    #!/bin/sh
    cd extern/xdev
    merlin32 -V xdev.s
    cd ../../
    cp extern/xdev/xdev.bin {{firmware_dir}}

fnxmgr:
    #!/bin/sh
    cd extern/fnxmgr/FoenixMgr
    cp fnxmgr.py __main__.py
    rm ../../../shipping/firmware/fnxmgr.zip
    zip ../../../shipping/firmware/fnxmgr.zip *.py -x fnxmgr.py
    rm __main__.py
    cd ../../..

fmanager:
    #!/bin/zsh
    cp build_fman_tmp.sh extern/F256jr-FileManager
    cd extern/F256jr-FileManager
    perl strings2binary.pl strings
    zsh build_fman_tmp.sh {{fman_dir}}
    cp build_cc65/fm_install/flash/fm.0? ../../shipping/firmware/
    cp build_cc65/fm_install/flash/*.csv ../../shipping/firmware/bulk_alternative

fnxmgr-install: fnxmgr
    #!/bin/sh
    unzip -o shipping/firmware/fnxmgr.zip -d $HOME/.local/share/FoenixMgr/FoenixMgr

@flash port="/dev/ttyUSB0":
    cd {{firmware_dir}}; python fnxmgr.zip --target f256k --port {{port}} --flash-bulk bulk.csv

@flash-dos port="/dev/ttyUSB0": dos
    cd {{firmware_dir}}; python fnxmgr.zip --target f256k --port {{port}} --flash dos.bin --flash-sector 6

@flash-xdev port="/dev/ttyUSB0": xdev
    cd {{firmware_dir}}; python fnxmgr.zip --target f256k --port {{port}} --flash xdev.bin --flash-sector 1

@flash-docs-exe port="/dev/ttyUSB0": docs
    cd {{firmware_dir}}; python fnxmgr.zip --target f256k --port {{port}} --flash help.bin --flash-sector 10

@flash-basic port="/dev/ttyUSB0": basic
    cd {{firmware_dir}}; python fnxmgr.zip --target f256k --port {{port}} --flash-bulk ../../basic_bulk.csv

@flash-pexec port="/dev/ttyUSB0": pexec
    cd {{firmware_dir}}; python fnxmgr.zip --target f256k --port {{port}} --flash pexec.bin --flash-sector 7

@run-dos port="/dev/ttyUSB0": dos
    cd {{firmware_dir}}; python fnxmgr.zip --target f256k --port {{port}} --binary dos.bin --address A000

@clean:
    rm -rf {{build_dir}}

@clear:
	dd if=/dev/zero of=_zero.bin bs=1024 count=64
	fnxmgr --address 0 --binary _zero.bin
	rm _zero.bin

@release version="2023.next":
    rm -f f256_firmware_{{version}}.zip
    cp Changelog.md {{build_dir}}
    cp HowToUpgrade.md {{build_dir}}
    cp Versions.txt {{build_dir}}
    cd {{build_dir}}; zip -r ../f256_firmware_{{version}}.zip *